Feat module refactor

Add module router

Input:
name - (required) name of the router
subnet - (required) ID of the subnet as inbound of router
gateway - (required) ID of the network as outbound of router
admin_state - (optional) admin state of the router

Output:
id - ID of the router

Add module network

Input:
name - (required) name of the network
cidr - (required) define ip range of network

admin_state_up - (optional) admin state of the network
enable_dhcp - (optional) enable DHCP of the network
nameservers - (optional) List of DNS server for the network

Output:
id - ID of the network
subnet - ID of its subnet

Add module box

Input:
key_pair - (required) key pair name injected into instance
image_name - (required) image name to boot up instance
box_name - (required) name of instance
box_nets - (required) list of network object including id(net_id) and desired ip(ip_v4).

amount - (optional) amount of instance
  if greater than 1, will append index to the box name
  e.g. name: c, amount: 2 => c0, c1
box_size - (optional) flavor of instance. default to m1.medium
user_data - (optional) user_data used to config instance at boot time
floating_ip_pool - (optional) floating ip pool name. Won't attach floating ip if not passing in.

Output:
id - List of ID of instance(s)
image_id - ID of image that is used to launch the instance
network - Map of nodename to its network(s)
cpus - Number of vcpu in the instance
mem - Memory size of the instance
floating_ip - Map of nodename to its floating ip, if assigned

box/main.tf

+# always use the latest version of image
+data "openstack_images_image_v2" "box" {
+  name = var.image_name
+  most_recent = true
+}
+
+# to get more hardware details
+data "openstack_compute_flavor_v2" "box" {
+  name = var.box_size
+}
+
+# create node
+resource "openstack_compute_instance_v2" "box" {
+  name            = var.amount == 1 ? var.box_name : "${var.box_name}${count.index}"
+  image_id        = data.openstack_images_image_v2.box.id
+  flavor_id       = data.openstack_compute_flavor_v2.box.id
+  key_pair        = var.key_pair
+  security_groups = concat(["default"], var.sec_groups)
+  count           = var.amount
+  user_data       = var.user_data
+
+# define the networks of the instance
+  dynamic "network" {
+    for_each = var.box_nets
+    iterator = net
+    content {
+      uuid        = net.value.net_id
+      fixed_ip_v4 = net.value.ip_v4
+    }
+  }
+}
+
+# allocate floating ip for instance if needed
+resource "openstack_networking_floatingip_v2" "box" {
+  count = var.floating_ip_pool != "" ? var.amount : 0
+  pool = var.floating_ip_pool
+}
+
+# associate floating ip to the instance
+resource "openstack_compute_floatingip_associate_v2" "box" {
+  count = var.floating_ip_pool != "" ? var.amount : 0
+  floating_ip = openstack_networking_floatingip_v2.box[count.index].address
+  instance_id = openstack_compute_instance_v2.box[count.index].id
+}